Dave Mitchell's DigitalMicrograph™ Scripting Website

// Script to upload lens settings saved from TEM mode, back to the TEM

// A suitable image containing the TEM lens configuration can be created using the script 'Save Microscope Config DM'

// Only the lens settings are changed by this script, which invokes them in Free Lens Mode. To remove the changes and

// restore the microscope to its configuration prior to running this script, simply turn off Free Lens Mode.

// Run the script with SHIFT held down to list instructions

// This script will source a default directory for loading files. This directory can be set by running the companion script

// 'Save Microscope Config' (note it must be version 2.3 or later) with the ALT key held down.

// D. R. G. Mitchell, adminnospam@dmscripting.ocm (remove the nospam to make this work)

// version:20130528, v2.4, May 2013, www.dmscripting.com

// source the directory for opening and saving files that DM is currently using

string currentopensavepath

string applicationstring="open_save"

currentopensavepath=GetApplicationDirectory( 2,0)

// source the default directory (saved by holding down the ALT key when running the 'Save Microscope Config' script).

string newdefaultpath

number defpathexists=0, defpathisvalid=0

// The default directory will be used but only where it has been set (defpathexists=1) and it is not ="" ie nothing

// If no valid default directory is set, then it will revert to whatever DM is currently using (ie the last location

// from which a file was opened from or saved to).

defpathexists=getpersistentstringnote("Save Microscope Config:Default Path", newdefaultpath)

if(newdefaultpath!="") defpathisvalid=1

//function to read mode

string readmode()

{

string reply, numberstring

number pass

reply=JEOLcommand("MAGCOD",pass)

numberstring=mid(reply,11,2)

return numberstring

}

// List of instructions when command key is pressed at script execution

If (SHIFTdown())

{

result("1 This script will upload to the TEM, TEM lens and condenser stigmator settings previously stored in an appropriate image."+"\n"\

+"2 An appropriate image can be created using the 'Save Microscope Config DM' script FROM TEM MODE (NOT STEM mode)."+"\n"\

+"3 Lens values are saved in the image as Tags, and are also displayed in the image."+"\n"\

+"4 The microscope must be in TEM mode when you run this script."+"\n"\

+"5 Uploading takes about 10s."+"\n"\

+"6 A default directory for sourcing these data files can be set in 'Save Microscope Config' script - run it with ALT held down.\n\n"\

+"IMPORTANT to be able to talk to the TEM you must type in the command line EXT_1 at the TEM keyboard"+"\n"\

+"BEFORE running this script. If you don't, you'll keep getting error messages until you type in EXT_1"+"\n"\

+"(note _ means a space). When you've finished uploading/downloading lens values type in EXT_0 (at the TEM)"+"\n"\

+"to return to internal TEM control. D. Mitchell, v2.3, August 2007"+"\n")

exit(0)

}

string modestring=readmode()

if(modestring!="EM") // This script will only work if the microscope is in EM (ie TEM) mode and not STEM mode

{

Beep()

Okdialog("The microscope must be in TEM mode to use this script!")

exit(0)

}

else

{

// check to make sure the Results window is open - if not open it.

result("Note TEM must be in 'EXT_1' mode before this script will work"+"\n\n")

// Declare variables

number pass, i

string openpath

image lensdata

// Set the path for opening files to the default path saved from 'Save Microscope Config' - provided it is valid

if(defpathexists==1 && defpathisvalid==1)

{

SetApplicationDirectory( applicationstring, 0, newdefaultpath )

}

// Dialog to open the file and decide whether to proceed

showalert("Select data file from which to upload TEM settings from.\n\nUploaded settings can be cleared by turning off Free Lens Control.",2)

string filepath

if(OpenDialog(filepath))

{

lensdata:=OpenImage(filepath)

}

else

{

SetApplicationDirectory( applicationstring, 0, currentopensavepath )

exit(0)

}

showimage(lensdata)

updateimage(lensdata)

// Restore the default path back to what is was before running this script

SetApplicationDirectory( applicationstring, 0, currentopensavepath )

// Check that the uploaded file is of the appropriate type

modestring =getstringnote(lensdata,"Imaging Mode ")

if(modestring!="EM")

{

beep()

OKDialog("WARNING this does not appear to be data saved from TEM mode")

deleteimage(lensdata)

Exit(0)

}

if (!ContinueCancelDialog("Do you want to upload these settings?"))

{

if(twobuttondialog("Close this file","No","Yes")) exit(0)

else deleteimage(lensdata)

Exit(0)

}

// write the data back to the TEM

result("Upload in Progress"+"\n\n")

// Uploading lenses

JEOLcommand("LFCABS 0,&H"+getstringnote(lensdata,"lens 0"),pass)

for(i=1;i<12;i++)

{

JEOLcommand("LFCABS "+i+",&H"+getstringnote(lensdata,"lens "+i),pass)

openandsetprogresswindow("Uploading . . .","Lens = "+i,"")

}

//Uploading Condenser Stigmators

i=4

JEOLcommand("DFCABS "+i+","+getstringnote(lensdata,"deflector "+i+":X")+","+getstringnote(lensdata,"deflector "+i+":Y"),pass)

//clean up

string dataname=getname(lensdata)

if(!twobuttondialog("Upload of Lens Settings Complete.\n\nClose this Data File?", "No", "Yes")) deleteimage(lensdata)

result("Upload of '"+dataname+"' Complete"+"\n\n")

beep()

openandsetprogresswindow("","","")

}