Dave Mitchell's DigitalMicrograph™ Scripting Website

// Script to upload complete settings saved from TEM mode, back to the TEM

// The source information for this script is an image file containing all the relevant lens/deflector/stigmator information.

// This image file must be created using the script 'Save Microscope Config DM'.

// Launch with SHIFT held down to list instructions.

// This script sets all deflector settings too. Use this only to restore a jiggered column. To recall a custom lens setting

// use the companion script 'Upload TEM lenses to TEM'. This only sets lens settings and then in free lens mode - so any changes

// can be done. Changes to deflectors are not undone when switching off free lens mode.

// This updated script now uses a default directory for accessing data files created with the script 'Save Microscope Config'.

// The default directory is set by holding down the ALT key when running the Save Microscope Config script.

// D. R. G. Mitchell, adminnospam@dmscripting.com (remove the nospam to make this work)

// version:20130528, v2.4, May 2013, www.dmscripting.com

// Get the directory DM is currently using to open/save files to

string currentopensavepath, newdefaultpath

string applicationstring="open_save"

currentopensavepath=GetApplicationDirectory( 2,0)

//function to read mode

string readmode()

{

string reply, numberstring

number pass

reply=JEOLcommand("MAGCOD",pass)

numberstring=mid(reply,11,2)

return numberstring

}

// List of instructions when command key is pressed at script execution

If (SHIFTdown())

{

result("1 This script will upload to the TEM, all TEM lens/def/stig settings previously saved in a settings file."+"\n"\

+"2 A settings file (an image) can be created using the 'Save Microscope Config DM' script FROM,"+"\n"\

+" TEM MODE (NOT STEM mode). Values are saved in the image as Tags, and are also displayed."+"\n"\

+"3 The microscope must be in TEM mode when you run this script."+"\n"\

+"4 Uploading saved setting to the microscope takes about 10s."+"\n"\

+"5 Use this script with caution, only when you are sure you want to reset def and stig settings (as well as lenses)."+"\n"\

+"6 A default path for data files can be set by running 'Save Microscope Config' with the ALT key held down.\n\n"\

+"IMPORTANT to be able to talk to the TEM you must type in the command line EXT_1 at the TEM keyboard"+"\n"\

+"BEFORE running this script. If you don't, you'll keep getting error messages until you type in EXT_1"+"\n"\

+"(note _ means a space). When you've finished uploading/downloading lens values type in EXT_0 (at the TEM)"+"\n"\

+"to return to internal TEM control. D. Mitchell, v2.3, August 2007"+"\n")

exit(0)

}

// Check to make sure that the microscope is in TEM mode.

string modestring=readmode()

if(modestring!="EM")

{

Beep()

Okdialog("The microscope must be in TEM mode to use this script!")

exit(0)

}

else// Program starts here

{

result("Note TEM must be in 'EXT_1' mode before this script will work"+"\n\n")

// Declare variables

number pass, i

string openpath

image lensdata

// Dialog to open the file and decide whether to proceed

beep()

beep()

beep()

if(!twobuttondialog("Warning !!!!! This script will change current lens, deflector and stigmator settings. Use it only to restore a previous

column alignment"+"\n\n"+"Changes to Deflector and Stigmator settings will not be undone when Free Lens mode is turned off - Use

with Extreme Caution", "Proceed", "Abort"))

{

exit(0)

}

beep()

if(!twobuttondialog("Are you absolutely sure? - this is your last chance to abort!", "Proceed", "Abort"))

{

exit(0)

}

okdialog("Select a file to upload data from")

// Source the default directory (if it has been set)

string newdefaultpath

number defpathexists=0

number defpathisvalid=0

defpathexists=getpersistentstringnote("Save Microscope Config:Default Path",newdefaultpath)

if(newdefaultpath!="") defpathisvalid=1

// If defpathexists=1 - the default path has been set, and if the path is not = "" then it is probably valid ie defpathisvalid=1

if (defpathexists=1 && defpathisvalid==1)

{

// set the default path for opening and saving files to the default (temporarily)

SetApplicationDirectory( applicationstring, 0, newdefaultpath )

}

if(OpenDialog(openpath))

{

lensdata:=OpenImage(openpath)

}

else

{

SetApplicationDirectory( applicationstring, 0, currentopensavepath )

exit(0)

}

showimage(lensdata)

updateimage(lensdata)

// Restore the default directory

SetApplicationDirectory( applicationstring, 0, currentopensavepath )

// Check the settings file to see that its mode is correct (EM=TEM)

modestring =getstringnote(lensdata,"Imaging Mode ")

if(modestring!="EM")

{

beep()

OKDialog("WARNING this does not appear to be data saved from TEM mode")

deleteimage(lensdata)

Exit(0)

}

if (!ContinueCancelDialog("Do you want to upload these settings?"))

{

if(twobuttondialog("Close this file","No","Yes")) exit(0)

else deleteimage(lensdata)

Exit(0)

}

// write the data to the TEM

result("Upload in Progress"+"\n\n")

// Uploading lenses

JEOLcommand("LFCABS 0,&H"+getstringnote(lensdata,"lens 0"),pass)

for(i=1;i<12;i++)

{

JEOLcommand("LFCABS "+i+",&H"+getstringnote(lensdata,"lens "+i),pass)

}

//Uploading Deflectors and Stigmators

for(i=0;i<12;i++)

{

JEOLcommand("DFCABS "+i+","+getstringnote(lensdata,"deflector "+i+":X")+","+getstringnote(lensdata,"deflector "+i+":Y"),pass)

}

//clean up

string dataname=getname(lensdata)

if(!twobuttondialog("Upload of Lens/Deflector Settings Complete.\n\nClose this Data File?", "No", "Yes")) deleteimage(lensdata)

result("Upload of '"+dataname+"' Complete"+"\n\n")

beep()

openandsetprogresswindow("","","")

}