Dave Mitchell's DigitalMicrograph™ Scripting Website

// Function to export the data in the front-most image as tab-delimited text. This text file is

// a script file with the extension .s, but it is in fact identical to a plain text (.txt) file. To import the tabbed text file (.s) into

// Excel, simply open the saved file in Excel and accept all the default import prompts.

// This first column is x and the second y and the third the value. The script picks up the

// calibration and will prompt with it. Selecting that calibration will set x and y values to distance

// from the origin (top left of the image). Setting it to 1 will return pixel positions.

// This will also work on a 1D spectrum or profile - the y column will be all zero.

// It is very for large (>512 x 512) images. An estimate of the processing time will be provided

// and the script progress is reported in the Progress window.

// D. R. G. Mitchell, adminnospam@dmscripting.com (remove the nospam to make this work)

// version:20130808, v1.0, Aug. 2013, www.dmscripting.com

// Declare function prototypes

documentwindow ExportasTabbedData(image profile, number pixelsize);

// Main program

number nodocs=countdocumentwindowsoftype(5)

if(nodocs<1)

{

showalert("Ensure an image or spectrum is front-most.",2)

exit(0)

}

// Source the front-most image

image front:=getfrontimage()

number xsize, ysize, scale

string units, imgname

getsize(front,xsize, ysize)

scale=front.imagegetdimensionscale(0)

units=front.imagegetdimensionunitstring(0)

imgname=getname(front)

result("\n\Exporting "+imgname+" as X/Y/Value tabbed text:")

result("\nCalibration = "+scale+" "+units+"\n\n")

// Export the image as tabbed text and display the result

number pixelsize=scale

If(!getnumber("Enter the pixel size = ",pixelsize,pixelsize)) exit(0)

documentwindow profiledata=ExportasTabbedData(front, pixelsize)

windowshow(profiledata)

profiledata.windowsetframeposition(138,0)

windowselect(profiledata)

imgname=windowgettitle(profiledata)

// Save the text file

if(!saveasdialog("Save Tabbed Text Data as . . .",imgname, imgname)) exit(0)

editorwindowsavetofile(profiledata,imgname)

// End of main program

// Function declarations

// Processing function: Pass in an image to create a tab delimited text file thereof in a script window.

// Then save the script window as a .s (script) file - this is plain text.

// Note this export is VERY slow for big images - it may take minutes. Be patient - it looks like the

// script has hung - it probably hasn't. Completion is shown in the Progress window.

documentwindow ExportasTabbedData(image profile, number pixelsize)

{

// Get some info on the passed in image

string imgname=getname(profile)

number scale, origin, xsize, ysize

string units

profile.imagegetdimensioncalibration(0, origin,scale,units,1)

getsize(profile, xsize, ysize)

number area =xsize*ysize

number processingtime=area/10000 // approximate processing time

// Put up a warning if processing time is getting long - NB time estimate is a bit rubbery

if(processingtime>10)

{

if(!twobuttondialog("Extimated processing time : "+format(processingtime,"%3.0f")+"s","Proceed","Cancel")) exit(0)

}

// create a text window to output the data

documentwindow textoutputwindow

textoutputwindow=NewScriptWindow(imgname+" (tabbed text)", 84,202, 726, 740)

// Loop through all the pixels extracting the data and writing it to the text window

number i,j, size, currentsize

size=xsize*ysize

For(j=0;j<ysize;j++)

{

openandsetprogresswindow("Working . . ",""+format(currentsize, "%3.0f")+" % complete","")

for(i=0; i<xsize; i++)

{

number pixelval=getpixel(profile, i,j)

number xval=i*pixelsize

number yval=j*pixelsize

currentsize=((i*j)/size)*100

editorwindowaddtext(textoutputwindow,format(xval,"%8.4f")+"\t"+format(yval, "%8.4f")+"\t"+pixelval+"\n")

}

}

// Return the textoutputwindow

openandsetprogresswindow("","","")

return textoutputwindow

}