Dave Mitchell's DigitalMicrograph™ Scripting Website

// Script to apply an edge damping filter prior to FFT filtering. This applies

// a damped edge around the image in which the intensity drops to zero in a 1/2 wave sinusoidal

// fashion. It helps remove the vertical/horizontal streaking artefacts seen in FFTs of images

// which arise due to the presence of a sharp discontinuity at the image edge.

// The damping is applied to the image before Fourier transformation. This approach

// is preferable to Butterworth or other circularly symmetric filters, since they damp

// according to radius, and contributions from image features close to the corners are lost.

// Only feature immediately adjacent to the edges are damped with this filter. The script

// requests the width of the damped edge in pixels. There seems little benefit in

// extending the width beyond 100 pixels. The edge width is set in the script so that it cannot

// exceed half the image width. Using such a large value creates a filter very similar to the Butterworth.

// D. R. G. Mitchell and J. O'Connell, adminnospam@dmscripting.com (remove the nospam to make this work)

// version:20130720, v1.0, www.dmscripting.com

// declare the function prototype

image createdampededge(number edgewidth, number ximagewidth, number yimagewidth);

// Main script

// source the front-most image - no size checking

image front:=getfrontimage()

number xsize, ysize

getsize(front, xsize, ysize)

string imgname=getname(front)

// Source the width of the edge damping - about 100 pixels seems to be good

number edgesize=100 // the width in pixels over which the edge is smoothed

if(!getnumber("Enter the width of the edge damping?", edgesize, edgesize)) exit(0)

// the damped edge size is limited to sensible values being less than half

// the width of the image. Using very large values creates a filter similar to the Butterworth.

if(edgesize>(xsize)/2) edgesize=xsize/2

if(edgesize>(ysize)/2) edgesize=ysize/2

// Create the damped edges filter

image filter=createdampededge(edgesize, xsize, ysize)

showimage(filter)

setname(filter, "Damped Edge Filter - Width "+edgesize)

// Multiply the image by th filter to reduce the impact of edges on the FFFT

image temp=front*filter

// Do the FFT

image fftimg=realfft(temp)

showimage(fftimg)

setname(fftimg, "FFT of "+imgname+" - Edge Damping "+edgesize)

// End of main script

// Function to create damped edges filter

image createdampededge(number edgewidth, number ximagewidth, number yimagewidth)

{

// Create images to hold each of the damped edges

// Use a sine function to creat a smooth transition

// The left hand edge

image left=realimage("",4,ximagewidth, yimagewidth)

left=((sin(((icol-(edgewidth/2))/edgewidth)*pi())+1)/2)

left=tert(icol>edgewidth, 1, left)

// Form the right hand edge by flipping the left hand edge image

image right=imageclone(left)

right=left[ximagewidth-icol, irow]

// Calculate the top edge

image top=imageclone(left)

top=((sin(((irow-(edgewidth/2))/edgewidth)*pi())+1)/2)

top=tert(irow>edgewidth, 1, top)

// Form the bottom edge by flippig the top image

image bottom=imageclone(left)

bottom=top[icol, yimagewidth-irow]

// Multiple the four images together , then threshold and scale them so that non-edge areas are 1

// while edge areas scale down from 1 to zero at the edge

image productimage=left*right*top*bottom

number threshval=getpixel(productimage, edgewidth, yimagewidth/2)

image edgeimage=tert(productimage>threshval, threshval, productimage)

edgeimage=edgeimage/threshval

return edgeimage

}