Dave Mitchell's DigitalMicrograph™ Scripting Website

// Script to read from a single text file containing x values, into a 1D plot. The text file is simply a file

// created in a simple text editor, a script window, Excel etc. Each line is delimited

// by a carriage return. To test this script, create a simple text file with several lines of numbers.

// Save the text file to the hard disk then open it with this script.

// D. R. G. Mitchell, December 2011

// version:2111218, v1.0

// adminnospam@dmscripting.com(remove the nospam to make this work)

// It is necessary to open a file for reading (openfileforreading()) to read from it.

// It must also be closed at the conclusion of reading, otherwise

// it will not be released to other attempts to do anything with it (if you try and open it with

// another program, Windows willl tell you that it is in use and can not be opened).

// The Try/Catch routine should ensure that it is closed after any

// error. The readfileline() function will read the file line by line and return

// 1 for every line it reads successfully. It will return 0 at the

// end of the file and this is used to detect the end of file. For more information

// search for 'File Input and Output' in DM's online help.

// This script is a useful way of reading in an experimental profile created in another software package.

// DM has an import funtion for reading text, but getting that to work can be a bit hit and miss.

// I often extract the relevant column of data and use this script to read it in. This of

// course pre-suposes that the interval between data points is constant, such as in an EDS spectrum.

// To use this script to read data where the x interval is not continuous, the missing data points would

// have to be set to zero.

// Often, one also needs to set the origin, scale and units of the axes to create a calibrated plot. This script prompts

// for these parameters and then calibrates the created spectrum. If these calibrations are not important

// simply click OK to accept the default values (origin=0, scale=1 and x and y units=""), and this will create

// an uncalibrated spectrum.

// variables

string path

number filereference

string thisline

// Select the file

path=""

documentwindow win

if(!opendialog(win,"Select a single column text file","",path)) exit(0)

// A very large file (10^6 channels) is used to store the data. The idea being that this will be

// large enough to hold all realistic data sets. The alternative is to read through the file once

// to work out how long it is, then read through it again to read in the data. The quick and dirty

// approach is used here.

image temp=realimage("",4,1000000,1) // really big file for storage.

number counter

// Try/Catch to open the file for reading but close it in case of error.

try

{

filereference=openfileforreading(path)

number readok=1

// While ever the end of file has not been reached (readok=0) read the next line

// and output it to the results

while(readok==1)

{

readok=readfileline(filereference, thisline)

temp[0,counter, 1, counter+1]=val(thisline)

result("\n"+counter+" "+val(thisline))

counter=counter+1

}

}

catch // there was an error - close the file

{

closefile(filereference)

showalert("Sorry there was an error",2)

exit(0)

}

// The file read has concluded, close the file for reading.

closefile(filereference)

image output=temp[0,0,1,counter]

deleteimage(temp)

// Show the image

showimage(output)

setwindowposition(output, 142,24)

updateimage(output)

// Prompt to see if the plot is to be calibrated

if(!twobuttondialog("Calibrate this plot?","Yes","No")) exit(0)

number originval=0

number scaleval=1

string xunitstring=""

string yunitstring=""

// Prompts are put up for the origin, scale and x and y axes units. As each is entered, the image

// is updated. This is purely for aethetics. Rather than updating each parameter

// individually (which takes code and time), a single command can do all three x axis parameters:

// imagesetdimensioncalibration(dimension, origin, scale, units, format). Format and dimension

// should be set to zero for a 1D plot. the intensity scale (y axis) has to be updated individually.

if(!getnumber("Enter the x axis value at the origin", originval, originval)) exit(0)

output.imagesetdimensionorigin(0,originval)

updateimage(output)

if(!getnumber("Enter the plot scale (channel width)", scaleval, scaleval)) exit(0)

output.imagesetdimensionscale(0,scaleval)

updateimage(output)

if(!getstring("Enter the x axis units", xunitstring, xunitstring)) exit(0)

output.imagesetdimensionunitstring(0,xunitstring)

updateimage(output)

if(!getstring("Enter the y axis units", yunitstring, yunitstring)) exit(0)

output.imagesetintensityunitstring(yunitstring)